Oracle游标

Oracle游标是通过关键字CURSOR的来定义一组Oracle查询出来的数据集,类似数组一样,把查询的数据集存储在内存当中,然后通过游标指向其中一条记录,通过循环游标达到循环数据集的目的。


游标的种类

Oracle游标可以分为显式游标和隐式游标两种之分。

显式游标:指的是游标使用之前必须得先声明定义,一般是对查询语句的结果事进行定义游标,然后通过打开游标循环获取结果集内的记录,或者可以根据业务需求跳出循环结束游标的获取。循环完成后,可以通过关闭游标,结果集就不能再获取了。全部操作完全由开发者自己编写完成,自己控制。

隐式游标:指的是PL/SQL自己管理的游标,开发者不能自己控制操作,只能获得它的属性信息。


显式游标

显式游标在实际开发中经常使用到,可以丰富PL/SQL的开发程序的编写,实现一些循环类的复杂业务。游标的使用步骤如下:

1、声明游标:

声明游标是给游标命名并给游标关联一个查询结果集,具体声明语法如下:

declare cursor cursor_name(游标名)
is select_statement(查询语句);

2、打开游标:

游标声明完,可以通过打开游标打开命令,初始化游标指针,游标一旦打开后,游标对应的结果集就是静态不会再变了,不管查询的表的基础数据发生了变化。打开游标的命令如下:

open cursor_name;

3、读取游标中数据:

读取游标中的数据是通过fetch into语句完成,把当前游标指针指向的数据行读取到对应的变量中(record 变量)。游标读取一般和循环LOOP一起使用,用于循环获取数据集中的记录。

fetch cursor_name into record变量

4、关闭游标:

游标使用完,一定要关闭游标释放资源。关闭后,该游标关联的结果集就释放了,不能够再操作了,命令如下:

close cursor_name;

案例1、创建一个游标循环打印学生信息表中学生基本信息,代码如下:

declare
  --定义游标
  cursor cur_xsjbxx is
    select * from stuinfo order by stuid;
  --定义记录变量  
  ls_curinfo cur_xsjbxx%rowtype;
begin
  open cur_xsjbxx;--打开游标
  loop
    FETCH cur_xsjbxx
      INTO ls_curinfo;--获取记录值
    EXIT WHEN cur_xsjbxx%NOTFOUND;
  
    dbms_output.put_line('学号:' || ls_curinfo.stuid || ',姓名:' ||
                         ls_curinfo.STUNAME);
  end loop;
  close cur_xsjbxx;--关闭游标
end;

结果如下:

oracle游标

代码解析:通常我们使用显式游标都是用来循环取数据集的,因此会经常如案例1一样,使用LOOP控制结果来搭配使用,通过游标的属性变量%NOTFUND来获取游标的结束,跳出LOOP循环。


显式游标的属性

我们利用显式游标的属性值来获取游标所处的状态,然后对应做相应的处理,常用的属性有四个:

1、%NOTFOUND。表示游标获取数据的时候是否有数据提取出来,没有数据返回TRUE,有数据返回false。经常用来判断游标是否全部循环完毕,如案例1%NOTFOUND为true的时候,说明循环完毕,跳出LOOP循环。

2、%FOUND。正好和%NOTFOUND相反,当游标提取数据值时有值,返回TRUE,否则返回FALSE。

3、%ISOPEN。用来判断游标是否打开。

4、%ROWCOUNT。表示当前游标FETCH INTO获取了多少行的记录值,用来做计数用的。


案例2、我们经常用到%ROWCOUNT作为游标的计数器,我们修改一下案例1的代码,用上%ROWCOUNT,代码如下:

declare
  --定义游标
  cursor cur_xsjbxx is
    select * from stuinfo order by stuid;
  --定义记录变量  
  ls_curinfo cur_xsjbxx%rowtype;
begin
  open cur_xsjbxx;--打开游标
  loop
    FETCH cur_xsjbxx
      INTO ls_curinfo;--获取记录值
    EXIT WHEN cur_xsjbxx%NOTFOUND;
    --利用游标计数器打印学生个数
    dbms_output.put('%rowcount计数器,第'||cur_xsjbxx%rowcount||'位学生,');
    dbms_output.put_line('学号:' || ls_curinfo.stuid || ',姓名:' ||
                         ls_curinfo.STUNAME);
  end loop;
  close cur_xsjbxx;--关闭游标
end;

结果如下:

Oracle游标


隐式游标

隐式游标虽然不能像显式游标一样具有操作性,但是在实际开发过程当中还是经常使用到它的属性值,隐式游标主要是用在select语句活DML语句时,PL/SQL程序会自动打开隐式游标,这个隐式游标是不受开发者控制的。下面看个例子。

案例3、隐式游标使用,代码如下:

declare
  ls_xsjbxx stuinfo%rowtype;
begin
  --查询学生信息
  select * into ls_xsjbxx from stuinfo t where t.stuid = 'SC201801001';
  if sql%found then
    dbms_output.put_line('学号:' || ls_xsjbxx.stuid || ',姓名:' ||
                         ls_xsjbxx.stuname);
  end if;

  --查询学生信息(不存在的学生)
  select * into ls_xsjbxx from stuinfo t where t.stuid = 'SC201901001';
  if sql%found then
    dbms_output.put_line('学号:' || ls_xsjbxx.stuid || ',姓名:' ||
                         ls_xsjbxx.stuname);
  end if;
exception
  when no_data_found then
    dbms_output.put_line('该学生SC201901001不存在');
end;

结果如下:

Oracle游标

代码解析:案例3我们可以发现,oracle隐式游标没有像显式游标一样声明游标名,直接采用SQL名称作为隐式游标的名称。然后可以利用游标的属性,做一些逻辑判断,隐式游标的属性值和显式的一样,有%NOTFOUND、%FOUND、%ROWCOUNT、%ISOPEN。显式游标表示的属性值都是对结果集行数的一些判断,而隐式游标对应的就是DML语句影响的行数。