PL/SQL异常处理

PL/SQL异常处理是PL/SQL块中对执行部分出现异常进行处理的部分。PL/SQL采用的是统一异常处理机制,当异常发生时,程序会自动跳转到异常处理部分,交给异常处理程序进行异常匹配,再调用对应的处理方法。如果程序出现异常,而没有找到对应的异常处理程序,则程序会直接中断抛出异常。PL/SQL异常可以分为预定义异常、非预定义异常、自定义异常三种。

PL/SQL异常处理都在PL/SQL块的最下方,以EXCEPTION开始,其语句结构如下:

declare
--声明部分
begin
--执行部分
exception
--异常部分
when  exception1 then 
--异常1处理程序
[when exception2  then 
--异常2处理程序 ]
[when others then 
--其它异常处理程序 ]
end;

语法解析:

1、exception是异常处理部分开始的标志。

2、when后面是跟着异常的名称, then后面是对应异常处理程序。也就是当异常exception1出现时,执行的是异常1处理程序。其它异常程序不会进入。

3、when others then 指的是异常再前面异常捕获中未捕获到对应的异常处理程序,则全部进入其它异常处理程序进行异常处理。


预定义异常

预定义异常Oracle数据库为我们预定义好开发过程当中经常出现的异常名称。Oracle一共提供了25种预定义异常名称,常用到的如我们使用select ...into语句进行赋值时,经常出现的NO_DATA_FOUND(select查询时无数据不能赋值给变量错误)、TOO_MANY_ROWS(查询返回记录不止一条,触发的错误)等。25种预定义异常,可以通过数据库语句查询,命令如下:

select *  from dba_source t where t.TEXT like '%EXCEPTION_INIT%' AND NAME='STANDARD';

结果如下:PL/SQL异常处理


案例1、测试预定义异常,代码如下:

declare
ls_stuinfo stuinfo%rowtype;
begin
  select t.* into ls_stuinfo
    from stuinfo t
   where t.stuid='SC2018010061';
   --该学号找不到对应的学生 
exception
  when no_data_found  then
     dbms_output.put_line('该学生在学生信息表中找不到');
end;

结果如下:

PL/SQL异常处理


非预定义异常

Oracle当中除了上面存在的25种预定义异常,更多存在的是非预定义的异常。也就是说,它们只存在错误编号和对应的错误信息,但是没有具体的错误名称的对应。虽然,Oracle数据库自己预定义了25种常见异常,但是对于其他异常,你可以选择为异常添加一个名称,使得它能够被异常处理模块进行捕获并抛出处理。

定义非预定义异常,可以分为两步走:

1、进行异常声明:声明一个异常名称。

2、进行异常名称和错误编号关联。

Oracle处理非预定义的异常和预定义异常的原理是一致的,非预定义异常只是自己给对应的Oracle错误编号起个自己的名字,而预定义异常是Oracle数据自己起的名字。


案例2、演示非预定义异常的编写,代码如下:

declare
  ex_only exception;--声明一个异常名称
  PRAGMA EXCEPTION_INIT(ex_only,-00001);--主键唯一性错误
begin
   update  stuinfo t set t.stuid='SC201801005'     
   where t.stuid='SC201801006'; 
exception
  --捕获异常
  when ex_only  then
     dbms_output.put_line('该学号已经存在,不应许修改');
  when others then 
     dbms_output.put_line(sqlerrm);  
end;

结果如下:

PL/SQL异常处理


自定义异常

除了,上面的预定义异常外,Oracle还为开发者提供一个异常处理方式,那就是自定义异常,可以根据自己实际的业务需求和逻辑错误进行自定义异常,并通过逻辑控制主动抛出自定义异常交给对应的异常处理模块,进行异常处理。进行自定义异常的步骤如下:

1、异常声明定义:在PL/SQL块的声明部分采用关键字EXCEPTION定义异常名称。

2、异常主动抛出:在PL/SQL块中执行部分,通过逻辑控制,主动使用RAISE关键字抛出异常,交给异常处理模块处理。

案例3、自定义异常演示,代码如下:

declare
  ex_check_sex exception;--声明一个异常名称
  ls_sex stuinfo.sex%type;
begin
   select t.sex into ls_sex from stuinfo t where t.stuid = 'SC201801006';
   dbms_output.put_line('该学生的性别是:'||ls_sex);--1:男,2:女
   if ls_sex not in ('1','2') then
     --性别不是1或者2主动抛出异常 
     raise ex_check_sex;
   end if;       
  
exception
  --捕获异常
  when ex_check_sex  then
     dbms_output.put_line('性别只能是男或者女');
  when others then 
     dbms_output.put_line(sqlerrm);  
end;

结果如下:

PL/SQL异常处理